Установка Adobe Reader 11 в тихом режиме с настройками

 

Для установки Adobe Reader 11 и некоторых настроек можно использовать следующий скрипт:

  • Отключен Adobe Updater
  • Отключен Защищенный режим Reader
  • Включен компонент ActiveX печати из Internet Explorer

 

@echo off

:: Устанавка Adobe Reader 11

:: Если 11 версия установлена, то применяем только настройки
IF EXIST "%ProgramFiles%\Adobe\Reader 11.0\Reader\AcroRd32.exe" goto already_installed
IF EXIST "%ProgramFiles(x86)%\Adobe\Reader 11.0\Reader\AcroRd32.exe" goto already_installed

:: Установка 11 версии
"%~dp0AdbeRdr11000_ru_RU.exe" /sAll
set exit_code=%ERRORLEVEL%
goto apply_settings

:already_installed
set exit_code=666

:apply_settings
:: Применение настроек

reg add "HKLM\SOFTWARE\Policies\Adobe\Acrobat Reader\11.0\FeatureLockDown" /v bUpdater /t REG_DWORD /d 0 /f
reg add "HKLM\SOFTWARE\Policies\Adobe\Acrobat Reader\11.0\FeatureLockDown" /v bProtectedMode /t REG_DWORD /d 0 /f
reg add "HKLM\SOFTWARE\Policies\Adobe\Acrobat Reader\11.0\FeatureLockDown" /v bEnhancedSecurityStandalone /t REG_DWORD /d 0 /f
reg add "HKLM\SOFTWARE\Policies\Adobe\Acrobat Reader\11.0\FeatureLockDown" /v iProtectedView /t REG_DWORD /d 0 /f

IF EXIST "%SystemRoot%\SysWOW64" (
reg add "HKLM\SOFTWARE\WOW6432Node\Adobe\Acrobat Reader\11.0\AdobeViewer" /v "EULA" /t REG_DWORD /d 1 /f
reg add "HKLM\SOFTWARE\WOW6432Node\Adobe\Acrobat Reader\11.0\AVAlert\cCheckbox\cAcrobat" /v "iWarnScriptPrintAll" /t REG_DWORD /d 1 /f
reg add "HKLM\SOFTWARE\WOW6432Node\Adobe\Acrobat Reader\11.0\EWH" /v "bExecutePrint" /t REG_DWORD /d 1 /f
) ELSE (
reg add "HKLM\Software\Adobe\Acrobat Reader\11.0\AdobeViewer" /v "EULA" /t REG_DWORD /d 1 /f
reg add "HKLM\Software\Adobe\Acrobat Reader\11.0\AVAlert\cCheckbox\cAcrobat" /v "iWarnScriptPrintAll" /t REG_DWORD /d 1 /f
reg add "HKLM\Software\Adobe\Acrobat Reader\11.0\EWH" /v "bExecutePrint" /t REG_DWORD /d 1 /f
)

exit /b %exit_code%

 

Тихая установка Reader выполняется командой:
AdbeRdr11000_ru_RU.exe /sAll

Причем при установке 11 версии Reader, предыдущие версии удаляются (до 9 версии).

 

Добавить комментарий

Do NOT follow this link or you will be banned from the site!