Смена часовых поясов в 02:00 27.03.2016. Для ОС Windows 7+

Батник на смену часовых поясов в 02:00 27.03.2016 в 4-х регионах. Возможно кому-то пригодится.

Инфо: 
http://www.worldtimezone.com/dst_news/dst_news_russia-map-2016-03.html

 

:: Установка часового пояса в Windows 7 x86, x64

:: Дата последнего изменения: 24.03.2016

:: ************************************************************************

:: ИСПОЛЬЗОВАНИЕ:
:: Задать переменной NEW_RTZ (ниже) часовой пояс (перечислены ниже), который необходимо установить.

::
:: Часовые пояса, которые необходимо установить
::

:: (UTC+04:00) Ижевск, Самара (RTZ 3)
set RTZ3=Russia Time Zone 3

:: (UTC+07:00) Красноярск (RTZ 6)
set RTZ6=North Asia Standard Time

:: (UTC+09:00) Якутск (RTZ 8)
set RTZ8=Yakutsk Standard Time

:: (UTC+11:00) Чокурдах (RTZ 10)
set RTZ10=Russia Time Zone 10

:: ************************************************************************
:: Выбор конкретного часового пояса, который будет установлен этим батником
:: ************************************************************************
set NEW_RTZ=%RTZ3%

::
:: Коды возврата батника
::

:: Не установлен Service Pack 1 для Windows 7
set ERR_WIN7_SP1_IS_NOT_INSTALLED=100

:: Не установлено обновление часовых поясов KB2998527
set ERR_KB2998527_IS_NOT_INSTALLED=200

:: Не найдена утилита %systemroot%\system32\tzutil.exe
set ERR_TZUTIL_IS_NOT_FOUND=300

:: Не найдена утилита %systemroot%\system32\systeminfo.exe
set ERR_SYSTEMINFO_IS_NOT_FOUND=301

:: В ОС не найден часовой пояс, который необходимо установить
set ERR_NEW_TZ_IS_NOT_FOUND=400

:: Ошибка установки нового часового пояса
set ERR_NEW_TZ_INSTALL_FAILED=500

:: Ошбика при проверке часового пояса после установки
set ERR_NEW_TZ_CHECK_FAILED=600

::
:: Лог файл
::
set LOG=%systemroot%\tz_change_2016_log.txt

::
:: Проверка ОС на возможность установки нового часового пояса
::

IF NOT EXIST "%systemroot%\system32\systeminfo.exe" exit %ERR_SYSTEMINFO_IS_NOT_FOUND%

:: Наличие SP1
systeminfo.exe | find /I "Service Pack 1"
IF %ERRORLEVEL% NEQ 0 exit %ERR_WIN7_SP1_IS_NOT_INSTALLED%

:: Наличие KB2998527
systeminfo.exe | find /I "KB2998527"
IF %ERRORLEVEL% NEQ 0 exit %ERR_KB2998527_IS_NOT_INSTALLED%

:: Наличие утилиты %systemroot%\system32\tzutil.exe
IF NOT EXIST "%systemroot%\system32\tzutil.exe" exit %ERR_TZUTIL_IS_NOT_FOUND%

:: Наличие часового пояса, который необходимо установить
tzutil.exe /l | find /I "%NEW_RTZ%"
IF %ERRORLEVEL% NEQ 0 exit %ERR_NEW_TZ_IS_NOT_FOUND%

::
:: Установка нового часового пояса
::
tzutil.exe /s "%NEW_RTZ%"
IF %ERRORLEVEL% NEQ 0 exit %ERR_NEW_TZ_INSTALL_FAILED%

::
:: Проверка был ли корректно установлен часовой пояс
::
tzutil.exe /g | findstr /I /R /C:"^%NEW_RTZ%$"
IF %ERRORLEVEL% NEQ 0 exit %ERR_NEW_TZ_CHECK_FAILED%

exit 0

Добавить комментарий

Do NOT follow this link or you will be banned from the site!